satellite/hosts/nixos/lapetus/services/jupyter.nix

{ config, pkgs, ... }:
# {{{ Jupyterhub/lab env
let appEnv = pkgs.python3.withPackages (p: with p; [
  jupyterhub
  jupyterlab
  jupyterhub-systemdspawner
  jupyter-collaboration
]);
  # }}}
in
{

  services.jupyterhub = {
    enable = true;
    port = 8420;

    jupyterhubEnv = appEnv;
    jupyterlabEnv = appEnv;

    extraConfig = ''
      c.LocalAuthenticator.create_system_users = False
      c.Authenticator.allowed_users = {'adrielus', 'javi'}
      c.Authenticator.admin_users = {'adrielus', 'javi'}

      c.Spawner.notebook_dir='${config.users.users.pilot.home}/projects/notebooks'
      c.SystemdSpawner.mem_limit = '2G'
      c.SystemdSpawner.cpu_limit = 2.0
    '';

    # {{{ Python 3 kernel
    kernels.python3 =
      let env = (pkgs.python3.withPackages (p: with p; [
        ipykernel
        numpy
        scipy
      ]));
      in
      {
        displayName = "Numerical mathematics setup";
        argv = [
          "${env.interpreter}"
          "-m"
          "ipykernel_launcher"
          "-f"
          "{connection_file}"
        ];
        language = "python";
        logo32 = "${env}/${env.sitePackages}/ipykernel/resources/logo-32x32.png";
        logo64 = "${env}/${env.sitePackages}/ipykernel/resources/logo-64x64.png";
      };
    # }}}
  };

  # {{{ Javi user
  sops.secrets.javi_password = {
    sopsFile = ../secrets.yaml;
    neededForUsers = true;
  };

  users.users.javi = {
    isNormalUser = true;
    hashedPasswordFile = config.sops.secrets.javi_password.path;
  };
  # }}}
  # {{{ Networking
  services.nginx.virtualHosts."jupyter.moonythm.dev" =
    config.satellite.proxy
      config.services.jupyterhub.port
      { proxyWebsockets = true; };
  # }}}
  # {{{ Storage
  environment.persistence."/persist/state".directories = [
    "/var/lib/${config.services.jupyterhub.stateDirectory}"
  ];
  # }}}
}