Cut down on a lot of flake inputs

modules/home-manager/compat/bemenu.nix

@@ -0,0 +1,54 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+  cfg = config.programs.bemenu;
+
+in
+{
+  meta.maintainers = [ hm.maintainers.omernaveedxyz ];
+
+  options.programs.bemenu = {
+    enable = mkEnableOption "bemenu";
+
+    package = mkPackageOption pkgs "bemenu" { };
+
+    settings = mkOption {
+      type = with types; attrsOf (oneOf [ str number bool ]);
+      default = { };
+      example = literalExpression ''
+        {
+          line-height = 28;
+          prompt = "open";
+          ignorecase = true;
+          fb = "#1e1e2e";
+          ff = "#cdd6f4";
+          nb = "#1e1e2e";
+          nf = "#cdd6f4";
+          tb = "#1e1e2e";
+          hb = "#1e1e2e";
+          tf = "#f38ba8";
+          hf = "#f9e2af";
+          af = "#cdd6f4";
+          ab = "#1e1e2e";
+          width-factor = 0.3;
+        }
+      '';
+      description =
+        "Configuration options for bemenu. See {manpage}`bemenu(1)`.";
+    };
+  };
+
+  config = mkIf cfg.enable {
+    assertions =
+      [ (hm.assertions.assertPlatform "programs.bemenu" pkgs platforms.linux) ];
+
+    home.packages = [ cfg.package ];
+
+    home.sessionVariables = mkIf (cfg.settings != { }) {
+      BEMENU_OPTS = cli.toGNUCommandLineShell { } cfg.settings;
+    };
+  };
+}

modules/home-manager/compat/k9s.nix

@@ -0,0 +1,28 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+  yamlFormat = pkgs.formats.yaml { };
+
+in {
+  options.programs.k9s = {
+    skins = mkOption {
+      type = types.attrsOf yamlFormat.type;
+      default = { };
+      description = ''
+        Skin files written to {file}`$XDG_CONFIG_HOME/k9s/skins/`. See
+        <https://k9scli.io/topics/skins/> for supported values.
+      '';
+      example = literalExpression ''
+        my_blue_skin = {
+          k9s = {
+            body = {
+              fgColor = "dodgerblue";
+            };
+          };
+        };
+      '';
+    };
+  };
+}

modules/home-manager/default.nix

@@ -3,6 +3,9 @@
 {
   # example = import ./example.nix;
 
+  bemenu = import ./compat/bemenu.nix;
+  k9s = import ./compat/k9s.nix;
+
   # Personal things
   firefox = import ./firefox;
   monitors = import ./monitors.nix;